"Trampelviecher" by Jens Bojaryn

 

Include German by Banbury & Christian Bluemke.

Include Default Messages by David Fisher.

Use explicit error messages.

 

The story headline is "Eine Halloween-Geschichte".

 

 

[---------------------------------------------------------]

Part Grundsätzliches

[---------------------------------------------------------]

 

Before listing nondescript items:

                change the Tisch to not marked for listing.    [Der Tisch wird schon in der Raumbeschreibung erwähnt. Er kann keine scenery sein, da man sonst nicht unterbinden kann, dass aufgelistet wird, was auf ihm liegt.]

 

Rule for writing a paragraph about a supporter:

                stop. [Geschmackssache.]

 

[Statuszeile]

When play begins, change the right hand status line to "".

When play begins, change the left hand status line to "Trampelviecher".

 

Use no scoring. [Ich mag keine Punkte.]

 

OfferHelp is a number variable. OfferHelp is -1.

Before reading a command while OfferHelp is -1:

                say "(Bitte gebe [italic type]info[roman type] oder [italic type]anleitung[roman type] ein, um mehr über das Spiel oder seine Steuerung zu erfahren.)";

                Now OfferHelp is 0. [Hilfsangebot nur beim ersten Zug.]

 

When play begins, say "Du hättest nein sagen sollen. Als Sebastian dich fragte, ob du mit ihm zur Halloween-Party gehst, hast du wieder nur 'Party' verstanden. Aber Halloween? Gibt es was Blöderes, als sich zu verkleiden? Du hast dir immer gesagt, daß du nicht auf diese Marketingtricks reinfällst. Wo kommen all die blöden Partys plötzlich her? Früher gab es die nicht."

 

When play ends, say "

 

...

 

...

 

...

 

Bleib du selbst.".

 

[YOURSELF]

The description of yourself is "Du heißt Markus Schnorb und trägst ein Riesenfledermauskostüm.[if metaller is trampelviech] Etwas regt sich in dir."

 

Instead of turning yourself, say "Es bringt dir nichts, dich vom Elend abzuwenden."

Instead of pushing yourself, say "Nicht jetzt. Nicht hier."

Instead of pulling yourself, say "Nichts passiert."

 

The Fledermauskostuem is worn by yourself. It is neuter.

The printed name of Fledermauskostuem is "Fledermauskostüm".

Understand "Kostuem","Riesenfledermauskostuem" as Fledermauskostuem.

The description is "Lächerlich und armselig!"

Instead of attacking or taking off the fledermauskostuem, say "Besser nicht, sonst sieht noch jemand deine Garfieldunterhose.".

 

 

[---------------------------------------------------------]

Part Partykeller

[---------------------------------------------------------]

 

The Im Partykeller is a room. "Frauen gäbe es hier, hat Sebastian gesagt. Jede Menge. Stattdessen siehst du lauter besoffene, langhaarige... Männer. Und sie hören die passende Musik dazu: Irgendwelche Haarspraymetaller versuchen, ihre Instrumente zu spielen. Jämmerlich. Auf einem Tisch in der Mitte des Raums steht das 'Buffet': Bockwürstchen und Tee mit Schnaps. Es ist aber [if the bockwurst is on the tisch]nur noch eine Bockwurst[otherwise]keine Bockwurst mehr[end if] übrig. Es ist neblig und es riecht nach Furz."

Instead of going nowhere from the im Partykeller, say "Was sollst du jetzt woanders? Es ist zwar schrecklich hier, aber bevor du in diesem Aufzug noch einmal rausgehst, mußt du dich erstmal kräftig betrinken."

Instead of going nowhere from the im Partykeller when the Metaller is Trampelviech, say "Du schaust auf die stampfenden Metaller. Vielleicht solltest du besser gehen? Unsicher machst du einen Schritt Richtung Ausgang...

 

Nein. Noch nicht.

 

Etwas hält dich zurück. Du willst bleiben."

 

A Metaller is a man. He is scenery.

The Metaller can be either Mensch or Trampelviech. The Metaller is Mensch. [Später ändert sich das...]

The printed name of Metaller is "Metaller[-n]". Metaller are plural-named.

Understand "Langhaariger", "Mann", "Betrunkener", "Besoffener", "jemand" as Metaller.

Understand "Langhaarige" and "Maenner" and "Besoffene" and "Betrunkene" as plural of Metaller.

Understand "Klauen", "Fell", "Hoerner", "hornig" as Metaller. [Gibt es einen einfachen Weg, "Klauen" etc. erst als "MEtaller" zu parsen, wenn die Verwandlung beginnt? Möglichst ohne zwei Objekte daraus zu machen.]

Understand "Tanz", "Stampfen", "Stampftanz" as Metaller.

Some Metaller are here.

The description of Metaller is "[if the metaller is a mensch]Die eine Hälfte der Männer trinkt, die andere schüttelt ihren Kopf zur Musik. Keiner beachtet dich. Du zweifelst daran, daß sie sprechen können.[otherwise]Die Metaller sind ganz in ihren Stampftanz vertieft.".

Instead of attacking or touching or pulling a metaller, say "[if the metaller is a mensch]'Geil Alter, Pogo!' Du wirst weggestoßen.[otherwise]Nichts zu machen - die Männer stampfen einfach weiter.".

Instead of kissing or taking or pushing or tasting a metaller, say "Selbst wenn du schwul wärst, würde das nicht in Frage kommen!".

Instead of asking a metaller about, try telling a metaller about.

Instead of telling a metaller about when the metaller is a mensch, say "Der Metaller ruft: '[one of]SLAYER!!!'[or]ICH WILL BIER!!!'[or]SATAN!!!'[or]DIE WHIMP!!!'[or]GEIL KOTZEN!!!'[or]FICKÖÖÖN!!!'[or]HAIL BROTHER!!!'[or]PLATZ DA!!!'[at random]". [Zufallsauswahl. Nett ist der Unterschied zu "purely at random".]

Instead of telling a metaller about when the metaller is a trampelviech, say "Die Metaller stampfen. Sie scheinen dich nicht wahrzunehmen".

Instead of showing or giving the hamsterkopf to the metaller, say "[if the metaller is a mensch]'Ey Bruder, machst einen auf Ozzy oder was?' Du wirst weggestoßen.[otherwise]Die Metaller stampfen. Sie scheinen dich nicht wahrzunehmen."

Instead of showing or giving the bockwurst to the metaller, say "'Boah, schon wieder Bockwurst. Alter, ich muss kotzen!' Du wirst weggestoßen."

 

The Nebel is male scenery.  It is here.

Understand "Kunstnebel" as Nebel.

The description of nebel is "Wahrscheinlich Kunstnebel."

 

The Tisch is a male supporter. It is here.

Understand "Buffet" as Tisch.

Instead of examining the tisch, try searching the Tisch.

Instead of entering or climbing the tisch, say "Du schwingst dich auf den Tisch, der dadurch ins Wanken gerät. Schnell springst du wieder runter, bevor er zusammenbricht."

Does the player mean eating the Tisch: it is very unlikely. [beim Essen wird "Buffet" so als "Wurst" verstanden]

 

The Bockwurst is female thing. It is on the Tisch. [Nicht "edible", da ich sowieso alle entsprechenden Befehle abfange.]

Understand "Wurst", "Wuerstchen", "letzt", "arm", "Buffet" as Bockwurst.

The description is "Das letzte arme Würstchen.".

Instead of eating or tasting the bockwurst, say "Du beißt ein Stückchen ab. Schmeckt nach Wasser.".

Instead of eating or tasting the bockwurst for at least the third time, say "Du weißt schon, dass sie nach Wasser schmeckt. Auf weitere Versuche hast du keine Lust."

Instead of inserting the bockwurst into the teekanne, say "Du dippst die Wurst kurz in den Tee."

Instead of inserting the bockwurst into the Erbrochene, say "Lieber nicht."

 

The Teekanne is a female container. It is scenery. It is on the Tisch.

Understand "Kanne", "Tee", "Schnaps", "Tee mit Schnaps" as Teekanne. ["Tee" und "Schnaps" sind das gleiche Objekt, ja. War halt einfacher.]

The description is "Eine Kanne Tee mit Schnaps. Oder Schnaps mit Tee? Jedenfalls rauchig.".

Instead of searching the Teekanne, try examining the Teekanne.

Instead of smelling the Teekanne, say "Riecht nach Schnaps.".

Instead of taking or eating or drinking or tasting the Teekanne, say "Du nimmst dir etwas Tee und stürzt das Zeug in einem Zug runter. Dein Rachen brennt und du siehst kurz Sterne. Schmeckt nach Selbstgebranntem.".

Instead of taking or eating or drinking or tasting the Teekanne when the Hamsterkopf is in the Teekanne, say "Tee mit Hamsteraroma? Niemals!".

After examining the Teekanne when the Hamsterkopf is in the Teekanne, say "In der Kanne schwimmt ein Hamsterkopf."

 

The Musik is female scenery.  It is here.

Understand "Krach", "Haarspraymetaller", "Refrain", "Saenger", "Band", "Instrumente" as Musik.

The description is "Der Sänger gröhlt irgendwas von Alkohol und Vergessen. Du hörst nicht weiter hin.".

Instead of attacking or switching off the musik, say "Das wäre der schnellste Weg, Selbstmord zu begehen.".

 

The Hamsterkopf is a male thing. It is here.

"In einer Ecke liegt ein Hamsterkopf.".

Understand "Kopf", "Hamster", "durchgeweicht^" as Hamsterkopf.

The description is "Bäh! Was für eine Schweinerei. Der Kopf ist echt. Mit Schrecken denkst du an deine Rennmäuse zu Hause.".

Instead of eating or tasting the hamsterkopf, say "Ja klar. Deine Leibspeise, was?".

Instead of examining the hamsterkopf when the hamsterkopf is in the teekanne, say "Ein mit Schnapstee durchweichter Hamsterkopf.".

Instead of taking the hamsterkopf when the hamsterkopf is in the teekanne, say "Den Kopf ist schon ganz durchgeweicht - den fischst du da besser nicht mehr raus.".

 

Sebastian is a man. He is here.

"Sebastian stiert vor sich hin."

Understand "Merkel" as Sebastian.

The description is "Sebastian hat sich als Merkel verkleidet. Das fand er richtig originell. Jetzt sitzt er auf dem Boden und stiert vor sich hin.".

Instead of asking sebastian about, try telling sebastian about.

Instead of telling sebastian about, say "'Sebastian? Können wir gehen?'[/n]Keine Reaktion.[/n]'Sebastian?'[/n]Nichts. Offenbar hat er sich mal wieder abgeschossen. Das hat dir noch gefehlt!"

Instead of attacking Sebastian, say "Du gibst Sebastian einen Tritt. Er würgt."

Instead of kissing or pulling or pushing or taking or touching or tasting Sebastian, say "Du hast Angst, dass er dich ankotzt. Hat er schonmal gemacht. Ist ja nicht das erste Mal, dass er dich zu sowas hier überredet hat."

Instead of showing or giving something to Sebastian, say "Sebastian scheint dich gar nicht zu bemerken. Er stiert weiter vor sich hin."

 

The Furz is male scenery. It is here.

Understand "pups" as Furz.

The description is "Ein Furz ist ein Furz. Mit leichtem Bieraroma.".

Instead of smelling or tasting the furz, try examining the furz.

 

The Erbrochene is neuter scenery.

The printed name of Erbrochene is "Erbrochene[-n]".

The description is "Eklig."

Understand "Kotze" as Erbrochene.

Instead of smelling or tasting or taking or eating the Erbrochene, say "Lieber nicht." [Was hoffentlich auch niemand ausprobiert...]

 

Instead of smelling, say "Es riecht nach Furz.".

 

 

[---------------------------------------------------------]

Part Handlung

[---------------------------------------------------------]

 

[Wie schnell zu erkennen, gibt es keine Möglichkeit, seinem Schicksal zu entrinnen.]

Every turn:

                if turn count is 3:

                               say "Jemand rempelt dich an.";

                if turn count is 6:

                               say "Ein Metaller kotzt sich auf die Füße.";

                               move Erbrochenes to the Partykeller;

                if turn count is 8:

                               say "Alle gröhlen den Refrain mit.";

                if turn count is 11:                                                             

                               if the player is carrying the bockwurst, say "Ein großer Mann nimmt dir die Bockwurst ab und isst sie.";

                               otherwise say "Ein großer Mann nimmt sich die Bockwurst und isst sie.";

                               remove bockwurst from play;

                if turn count is 14:

                               say "Jemand brüllt: 'Scheiße, ich will Bier!'";

                if turn count is 16:

                               say "Ein paar Metaller beginnen merkwürdig zu stampfen. So einen Tanz hast du noch nie gesehen.";

                               Now the Metaller is Trampelviech; [Ab hier verändern sich einige der Texte.]

                if turn count is 17:

                                say "Immer mehr Männer stampfen, nein: trampeln. Irgendwas geht hier vor.";

                if turn count is 18:

                               say "Alle um dich herum beginnen zu trampeln. Sie verändern sich: Ihre Füße werden zu hornigen Klauen, ihnen wächst Fell und sie bekommen drei Hörner.";

                if turn count is 19:

                               say "Deine Füße jucken. Du willst [if DancedWithTheViech is true]weiterstampfen.[otherwise]mitstampfen.";

                if turn count is 20:

                               say "Du stampfst. Ahh, tut so gut... ja, Klauen. Endlich Fell. Jetzt laufen. Mit ihnen laufen. Zu den anderen laufen. Sammeln. Trampeln. Laufen.";

                               end the game saying "*** ENDE ***";

                otherwise:

                               do nothing.

 

 

[---------------------------------------------------------]

Part Verben

[---------------------------------------------------------]

 

[Was alles nicht ohne Nachhilfe funktioniert...]

Understand  "dipp [something] in [something] [hinein]" as inserting it into.

Understand "red mit [something]" as telling it about.

Understand "rempel [someone] an" as attacking.

Understand "groehl" as singing.

Understand "schalt [something] aus" as switching off.

Understand "stoepsel [something] aus" as switching off.

Understand "schalt [something] an" as switching on.

Understand "zieh [something]" as pulling.

Understand "drueck [something]" as pushing.

Understand "schuettel [something]" as pushing.

Understand "schubs [something]" as attacking.

Understand "spring auf [something]" as entering.

Understand "schwing [dich] auf [something]" as entering.

Understand "setz [dich] auf [something]" as entering.

Understand "drehe [something] um" as turning.

Understand "drehe [something]" as turning.

 

[Neue Verben]

Farting is an action applying to nothing.

Understand "furz" or "pups" as farting.

Report farting:

                say "Du erweiterst das Aroma des Partykellers um eine weitere Note."

 

Dancing is an action applying to nothing.

Understand "tanz" or "trampel" or "stampf" as dancing.

Report dancing:

                say "Zu dieser Musik tanzt du nicht!"

 

DancedWithTheViech is a truth state that varies. DancedWithTheViech is usually false. [truth state = bool... danach habe ich lange gesucht!]

Instead of dancing when the metaller is trampelviech:

                say "Du stampfst mit den anderen. Es kribbelt. Du bist nicht mehr allein.";

                Now DancedWithTheViech is true.

 

Weeping is an action applying to nothing.

Understand "wein" or "schluchz" or "heul" as weeping.

Report weeping:

                say "Dir ist wirklich zum Heulen zumute. Aber du hast Angst, dass die anderen dich auslachen."

 

Screaming is an action applying to nothing.

Understand "bruell", "ruf", "schrei" as screaming.

Report screaming:

                say "Dein Schrei wird von der lauten Musik verschluckt."

 

Laughing is an action applying to nothing.

Understand "lach" or "schmunzel" or "grins" or "laechl" as laughing.

Report laughing:

                say "Du lachst leise in dich hinein."

 

Thanking is an action applying to nothing.

Understand "danke" or "danke schoen" as thanking.

Report Thanking:

                say "Keine Ursache."

 

Saying please is an action applying to nothing.

Understand "bitte" as saying please.

Report saying please:

                say "Danke."

 

Vomitting is an action applying to nothing.

Understand "kotz" or "brech" or "wuerg" or "erbrech [dich]" as vomitting.

Report vomitting:

                say "Zwar ist dir nach würgen, wenn du das Elend hier siehst, aber es wirklich zu tun hieße, sich auf eine Stufe mit den Gästen dieser Party zu stellen."

 

Getting manual is an action out of world applying to nothing. ["out of world"=es vergeht kein Zug. Gibt es einen einfachen Weg, Befehle nachträglich als "out of world" zu deklarieren (z.B. "lage")?]

Understand "anleitung" or "hilfe" as getting manual.

Report getting manual:

                say "Trampelviecher ist Interactive Fiction (auch Textadventure genannt). Du kannst bestimmen, was der Protagonist des Spieles tun soll, indem du ihm Befehle gibst. Einige Beispiele:[/n]

 

    >untersuche sebastian (kurz: u sebastian)[/n]

    >untersuche dich[/n]

    >nimm hamsterkopf[/n]

    >lege den hamsterkopf auf den tisch[/n]

    >rede mit metaller[/n]

    >gehe nach draußen[/n]

    >iss bockwurst[/n]

    >warte

 

Der Parser versteht noch eine ganze Reihe anderer Verben. Probier es aus! Hier noch ein paar spezielle Befehle:[/n]

 

    >inventar (kurz: i) - zeigt an, was du bei dir trägst[/n]

    >lage (kurz: l) - gibt die Raumbeschreibung aus[/n]

    >speichern - Spielstand speichern[/n]

    >laden - Spielstand laden[/n]

    >ende - Spiel beenden[/n]

    >info - mehr über das Spiel erfahren[/n]

"

 

Getting Credits  is an action out of world applying to nothing.

Understand "credits" or "info" as getting credits.

Report getting credits:

                say "Trampelviecher war ursprünglich mein Beitrag zum deutschen Speed-IF 1 im November 2002. Es ging darum, in nur zwei Stunden ein Textadventure zum Thema 'Warum Halloween in deutschsprachigen Landen gefährlich ist' zu schreiben. Das Ergebnis kann man immer noch auf meiner Homepage finden.

 

Die hier vorliegende Version habe ich ein wenig erweitert, von den gröbsten Fehlern befreit und - vor allem - nach Inform 7 portiert. Natürlich ist das Spiel immer noch sehr kurz.

 

Mein Dank gilt:[/n]Jan Bojaryn und Fla fürs Betatesten[/n]Banbury und Christian Bluemke für die German-Extension von Inform 7[/n]Gunther Schmidl fürs Ausrichten des Speed-IFs

 

Ich freue mich sehr über Kommentare zum Spiel: [bold type]http://tanan.de/tanmail.htm[roman type][/n]Mai 2009, Jens Bojaryn

 

P.S. Nein, das Spiel hat keine Lösung, nur ein Ende. Entspann dich."

 

 

[---------------------------------------------------------]

Part Library Messages

[---------------------------------------------------------]

 

[Funktioniert nur mit der Extension "Default Messages"]

Table of custom library messages (continued)

Message Id            Message Text

LibMsg <empty line>         "Bitte gib ein, was du tun möchtest.[/n]"

LibMsg <cannot take yourself>        "Nicht jetzt. Nicht hier.[/n]"

LibMsg <block listening>  "Du hörst nur die furchtbare Musik.[/n]"

LibMsg <report player touching self>             "Nicht jetzt. Nicht hier.[/n]"

LibMsg <block saying yes>               "Nein![/n]"

LibMsg <block saying no>                               "Doch![/n]"

LibMsg <block saying sorry>            "Macht nichts.[/n]"

LibMsg <block swearing obscenely>              "So ist es nunmal.[/n]"

LibMsg <block swearing mildly>                     "So ist es nunmal.[/n]"

LibMsg <block jumping>                  "Du springst einmal auf der Stelle. Nichts passiert. Noch immer alles furchtbar.[/n]"

LibMsg <block waving hands>                                        "Du winkst. Niemand beachtet dich.[/n]"

LibMsg <block attacking>                                               "Du bist sauer - aber nicht auf [den noun]![/n]"

LibMsg <block rubbing>                                                  "Nichts passiert. Noch immer alles furchtbar.[/n]"

LibMsg <report player waiting>                                      "Die Gegenwart hält an.[/n]"

LibMsg <block throwing at>                                            "Du warst noch nie ein großer Werfer.[/n]"

LibMsg <throw at inanimate object>                             "Du warst noch nie ein großer Werfer.[/n]"

LibMsg <report player turning>                                      "Nichts passiert. Noch immer alles furchtbar.[/n]"

LibMsg <cannot push something fixed in place>         "Nichts passiert. Noch immer alles furchtbar.[/n]"

LibMsg <cannot pull something fixed in place>           "Nichts passiert. Noch immer alles furchtbar.[/n]"

LibMsg <block singing>                                                   "Du tust so, als würdest du mitsingen.[/n]"

LibMsg <block thinking>                                                 "Dir fällt nichts ein.[/n]"

LibMsg <block sleeping>                  "Es ist zu laut hier![/n]"

 

 

[---------------------------------------------------------]

Part Debug

[---------------------------------------------------------]

 

[### gibt Testern die Möglichkeit, eine Nachricht an mich zu schreiben, die vom Programm ignoriert wird.]

After reading a command:

                if the player's command includes  "###":

                               reject the player's command.

 

 

Test me with "u sebastian / schüttel sebastian /rede mit sebastian /u wurst /nimm wurst /iss sie /u kopf /nimm ihn /lege kopf in kanne /u kanne /rede mit metaller /küss metaller /schalte musik aus /furze /rieche /raus /raus /u metaller /stampfe /u mich "